设为首页收藏本站

兄弟外汇论坛|股票论坛|期货论坛

 找回密码
 注册

QQ登录

只需一步,快速开始

搜索
查看: 5798|回复: 3

[MT编程教学] MT4自带的EA :Moving Average 详解

  [复制链接]
发表于 2009-1-7 19:39:52 | 显示全部楼层 |阅读模式
//+------------------------------------------------------------------+
//|                                               Moving Average.mq4 |
//|                      Copyright ?2005, MetaQuotes Software Corp. |
//|                                       http://www.metaquotes.net/ |
//+------------------------------------------------------------------+
#define MAGICMA  20050610 //定义本EA操作的订单的唯一标识号码

extern double Lots               = 0.1;//每单的交易量
extern double MaximumRisk        = 0.02;//作者定义的最大风险参数
extern double DecreaseFactor     = 3;//作者定义的参数,作用要看程序中的用法
extern double MovingPeriod       = 10;//EA中使用的均线的周期
extern double MovingShift        =3;//EA中使用的均线向左的K线偏移量
//+------------------------------------------------------------------+
//| Calculate open positions                                         |
//+------------------------------------------------------------------+
int CalculateCurrentOrders(string symbol)//函数作用,计算当前持仓订单的数量
  {
   int buys=0,sells=0;//定义两个临时变量,准备用于后面的多空订单的个数计算
//----
   for(int i=0;i<OrdersTotal();i++)//循环检测当前的订单队列
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES)==false) break;//挑出持仓单的每一个订单位置
      if(OrderSymbol()==Symbol() && OrderMagicNumber()==MAGICMA)//根据订单位置,比较是否是当前K线商品 以及订单唯一标识号是否和本程序设置的一致(用于避免EA误操作其他程序控制的持仓单)
        {
         if(OrderType()==OP_BUY)  buys++;//找到符合条件的持仓单后,如果是多单,则临时变量buys增加1
         if(OrderType()==OP_SELL) sells++;//找到符合条件的持仓单后,如果是空单,则临时变量sells增加1
        }
     }
//---- return orders volume
   if(buys>0) return(buys);
   else       return(-sells);//本函数返回查询计算结束时的持仓单的个数。
  }
//+------------------------------------------------------------------+
//| Calculate optimal lot size                                       |
//+------------------------------------------------------------------+
double LotsOptimized()//函数目的,根据要求 计算出订单交易量
  {
   double lot=Lots;
   int    orders=HistoryTotal();     // history orders total 历史出场订单的个数
   int    losses=0;                  // number of losses orders without a break
//---- select lot size
   lot=NormalizeDouble(AccountFreeMargin()*MaximumRisk/1000.0,1);//通过风险系数的计算获得当前入场单应该采用的交易量
//---- calcuulate number of losses orders without a break
   if(DecreaseFactor>0)
     {
      for(int i=orders-1;i>=0;i--)
        {
         if(OrderSelect(i,SELECT_BY_POS,MODE_HISTORY)==false) { Print("Error in history!"); break; }//循环查询出场单队列
         if(OrderSymbol()!=Symbol() || OrderType()>OP_SELL) continue;//
         //----
         if(OrderProfit()>0) break;
         if(OrderProfit()<0) losses++;//循环计算所有出场亏损单的亏损总和
        }
      if(losses>1) lot=NormalizeDouble(lot-lot*losses/DecreaseFactor,1);//如果亏损额大于1,则下一入场单的交易量修正为新的计算结果。
     }
//---- return lot size
   if(lot<0.1) lot=0.1;//如果计算出的交易量小于帐户最小手数0.1,则下一入场单的交易手数使用0.1作为交易量
   return(lot);
  }
//+------------------------------------------------------------------+
//| Check for open order conditions                                  |
//+------------------------------------------------------------------+
void CheckForOpen()//检查入场条件的情况并作处理
  {
   double ma;
   int    res;
//---- go trading only for first tiks of new bar
   if(Volume[0]>1) return;//如果当前K线持仓量大于1,说明不是K线的开盘时间点,则直接返回 否则是K线第一个价格,则继续下面的过程
//---- get Moving Average
   ma=iMA(NULL,0,MovingPeriod,MovingShift,MODE_SMA,PRICE_CLOSE,0);//获得当前的均线数值
//---- sell conditions
   if(Open[1]>ma && Close[1]<ma)  //如当前K开盘价大于均线,而前一K收盘价小于均线,则发出入场多单
     {
      res=OrderSend(Symbol(),OP_SELL,LotsOptimized(),Bid,3,0,0,"",MAGICMA,0,Red);
      return;
     }
//---- buy conditions
   if(Open[1]<ma && Close[1]>ma)  //如当前K开盘价小于均线,而前一K收盘价大于均线,则发出入场空单
     {
      res=OrderSend(Symbol(),OP_BUY,LotsOptimized(),Ask,3,0,0,"",MAGICMA,0,Blue);
      return;
     }
//----
  }
//+------------------------------------------------------------------+
//| Check for close order conditions                                 |
//+------------------------------------------------------------------+
void CheckForClose()//检查出场条件的情况并作处理
  {
   double ma;
//---- go trading only for first tiks of new bar
   if(Volume[0]>1) return;
//---- get Moving Average
   ma=iMA(NULL,0,MovingPeriod,MovingShift,MODE_SMA,PRICE_CLOSE,0);
//----
   for(int i=0;i<OrdersTotal();i++)
     {
      if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES)==false)        break;
      if(OrderMagicNumber()!=MAGICMA || OrderSymbol()!=Symbol()) continue;
      //---- check order type
      if(OrderType()==OP_BUY)
        {
         if(Open[1]>ma && Close[1]<ma) OrderClose(OrderTicket(),OrderLots(),Bid,3,White);//如果持仓是多单,则当当前K开盘价小于均线,而前一K收盘价大于均线,则发出平仓指令
         break;
        }
      if(OrderType()==OP_SELL)
        {
         if(Open[1]<ma && Close[1]>ma) OrderClose(OrderTicket(),OrderLots(),Ask,3,White););//如果持仓是空单,则当当前K开盘价大于均线,而前一K收盘价小于均线,则发出平仓指令

         break;
        }
     }
//----
  }
//+------------------------------------------------------------------+
//| Start function                                                   |
//+------------------------------------------------------------------+
void start()//主循环过程
  {
//---- check for history and trading
   if(Bars<100 || IsTradeAllowed()==false) return;
//---- calculate open orders by current symbol
   if(CalculateCurrentOrders(Symbol())==0) CheckForOpen();
   else                                    CheckForClose();
//----
  }
//+------------------------------------------------------------------+
回复

使用道具 举报

发表于 2016-11-17 19:14:59 | 显示全部楼层
有KDJ交叉报警弹窗的指标吗
回复 支持 反对

使用道具 举报

发表于 2017-4-1 08:22:01 | 显示全部楼层
希望大家踊跃发言,我顶先
回复 支持 反对

使用道具 举报

发表于 2017-5-19 12:59:03 | 显示全部楼层
不错不错,很好很好,谢谢分享
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则

QQ|小黑屋|手机版|Archiver|兄弟财经    

GMT+8, 2017-9-22 10:37 , Processed in 3.190483 second(s), 19 queries .

Powered by Discuz! X3.1

© 2001-2013 Comsenz Inc.

快速回复 返回顶部 返回列表